PowerPointで正確な1/4円（四分円）を作る方法

PowerPointで正確な1/4円（四分円）を図形を組み合わせて作る方法をご紹介します。

図形の「部分円」でアバウトな1/4円を作ることはできますが、もっと正確に作りたいという方におすすめのテクニックです。

合わせて、PowerPoint VBAを使って1/4円を作るマクロと1/6円の作り方もご紹介します。

この記事の目次

1/4円を適当に作る
1/4円を正確に作る
マクロで1/4円を作る
1. コード
2. 実行結果
1/6円を作る

1/4円を適当に作る

図形の「部分円」を使うとアバウトな1/4円を作ることができます。

「ホーム」タブ →「図形描画」→「部分円」を選択します。

スライドをクリックすると3/4円が描けます。

上または右の調整ハンドルを回転させると1/4円に変形することができます。

しかし、調整ハンドルが円の1/4の位置でぴったり固定されず、目分量で合わす必要があるので調整が困難です。

プレースホルダーも余白が多くなり、整列がしづらい形状になるため、あまり美しい作り方とは言えません。

1/4円を正確に作る

図形を組み合わせて結合すると1/4円を正確に作ることができます。

「ホーム」タブ →「図形描画」→「楕円」を選択します。

スライドをクリックして正円を描きます。

続いて、「図形描画」→「L字」を選択します。

スライドをクリックすると正円と同じサイズのL字が描けます。

正円とL字を上下左右中央揃え（揃え方を参照）で配置します。説明のためL字の色を変更しています。

図形を「Ctrl + A」キーですべて選択し、「図形の書式」タブ →「図形の挿入」グループ →「図形の結合」→「単純型抜き」をクリックします。

1/4円の完成です。

マクロで1/4円を作る

1/4円は、マクロを使うと自動で作れます。図形の結合で作ると手間がかかるため、頻繁に作るのであれば自動化しておくのがおすすめです。

コード

Sub 図形の1分の4円を作成()

    Dim n As Long
    Dim w As Double
    Dim h As Double
    Dim diameter As Double
    Dim shp As Shape
    
    '選択中のスライド番号を取得
    n = ActiveWindow.Selection.SlideRange.SlideIndex
    
    'スライドサイズ取得
    w = ActivePresentation.PageSetup.SlideWidth
    h = ActivePresentation.PageSetup.SlideHeight
    
    '円の直径「cm」を入力
    diameter = 6
    
    '直径を「pt」に変換
    diameter = Round(diameter * 720 / 25.4, 1)

    With ActivePresentation

        '正円を作成
        Set shp = .Slides(n).Shapes.AddShape( _
        Type:=msoShapeOval, _
        Left:=(w - diameter) / 2, _
        Top:=(h - diameter) / 2, _
        Width:=diameter, _
        Height:=diameter)
        
        '図形の色
        shp.Fill.ForeColor.RGB = RGB(0, 0, 0)
        '図形の線なし
        shp.Line.Visible = msoFalse
        '図形の名前
        shp.Name = "shp1"
        
        '長方形を作成
        Set shp = .Slides(n).Shapes.AddShape( _
        Type:=msoShapeRectangle, _
        Left:=(w - diameter) / 2, _
        Top:=(h - diameter) / 2 + diameter / 2, _
        Width:=diameter, _
        Height:=diameter / 2)

        '図形の名前
        shp.Name = "shp2"
        
        '長方形を作成
        Set shp = .Slides(n).Shapes.AddShape( _
        Type:=msoShapeRectangle, _
        Left:=(w - diameter) / 2, _
        Top:=(h - diameter) / 2, _
        Width:=diameter / 2, _
        Height:=diameter)

        '図形の名前
        shp.Name = "shp3"
        
        '3つの図形を単純型抜き
        .Slides(n).Shapes.Range(Array("shp1", "shp2", "shp3")) _
        .MergeShapes (msoMergeSubtract)

    End With
End Sub